Añadir descripción a una función y a sus argumentos en Excel con VBA

Problema

Queremos añadir una descripción a una función definida por el usuario (UDF) y a sus argumentos en Excel mediante VBA. Por ejemplo a la siguiente función:

Function MAYUSCULAS(Núm_función As Integer, Texto As Range)

    Select Case Núm_función
        Case 0 ' No: minúsculas
        MAYUSCULAS = LCase(Texto)
        Case 1 ' Sí: MAYÚSCULAS
        MAYUSCULAS = UCase(Texto)
        Case Else ' Resto: Nombre Propio
        MAYUSCULAS = WorksheetFunction.Proper(Texto)
    End Select
    
End Function

Solución

1. Abrimos el Editor de Microsoft Visual Basic: Alt+F11.
2. Creamos la siguiente subrutina en un módulo.

Sub AsignaDescripciones()

   Dim FuncName As String
   Dim FuncDesc As String
   Dim Category As String
   Dim ArgDesc(1 To 2) As String
       
   FuncName = "MAYUSCULAS"
   FuncDesc = "Convierte una cadena de texto a minúsculas MAYÚSCULAS o Nombre Propio"
   Category = 7 'Categoría de texto
   ArgDesc(1) = "Número indicando la conversión. 0: minúsculas. 1: MAYÚSCULAS. Otro número: Nombre Propio."
   ArgDesc(2) = "Texto (celda) que deseamos convertir"
  
   Application.MacroOptions _
      Macro:=FuncName, _
      Description:=FuncDesc, _
      Category:=Category, _
      ArgumentDescriptions:=ArgDesc

 End Sub

3. Ejecutamos la subrutina.
4. La descripción de la función y de los argumentos estarán disponibles en el libro de Excel que almacena dicha función. Si queremos modificar la información, cambiamos el código y la ejecutaremos de nuevo.
• Descripción y primer argumento

• Segundo argumento

Entradas relacionadas

• Añadir una descripción a las funciones definidas por el usuario en Excel
• Convertir texto de URL en enlaces activos
• Abrir ficheros y aplicaciones con cuadro de diálogo e hipervínculo en Excel
• Eliminar todos los hipervínculos de una hoja o libro con VBA
• Comprobar si una celda contiene un hipervínculo

Referencias

• Método Application.MacroOptions (Excel)